www.howardism.org
Babblings of an aging geek in love with the Absurd, his family, and his own hubris.... oh, and Lisp.

Online Meeting Etiquette

I have been in many meetings over the years where the presenter’s screen is more of a distraction. Once, while the Scrum Master was sharing his screen of our backlog and yelling about how we needed to work hard to meet our yearly goals, a mail notification showed up for him that said, Thank you for your resume submission. We’ll be back in touch with you. Needless to say, the meeting should have been canceled at that point.

Here are a few suggestions for you:

  1. Do Not Disturb mode. Stop email messages from popping up in the meeting by either of the following tricks:
    • Open the Notification Center by clicking the small icon right next to the Finder in the upper right hand corner of your screen. With the mouse cursor inside the notification box, scroll down and you’ll see a switch to toggle notifications.
    • Easier method is to hold down the Option key while clicking the Notification Center icon.
  2. DND Skype. Skype has a feature called Do Not Disturb (which you can pull down from the Skype icon in the top-right menu).
  3. Full Screen the Browser. Most meetings involve showing off a web page. Put it in Presentation Mode (Shift-Command-F) to fill up the screen and maximize your screen estate.
  4. Hide the Dock. Little animations and colorful icons with numbers on them are often more interesting the content you’re discussing.
  5. Activate Caffeine. Caffeine is a free little toolbar app that allows you to turn on/off the screen saver.

Automated Approach

I read this article about creating an Automator Workflow and associating it with your calendar. While this approach may be good, I only want to do the steps above when I’m sharing my desktop, so allow me to propose doing all of these steps with one fell swoop with some magical AppleScript. Doing this requires a simple two step process.

Turn on the Scripts

First, you need to be quickly run a script. You can have a bunch of little scripts (and these can be Python and other shell scripts if you don’t want to do that AppleScript thing).

Open up the AppleScript Editor application, and go to the General tab and turn on the script menu.

meeting-etiquette-scripts-on.png

At this point, you’ll have a little pull-down menu in the top-right corner where you can run scripts like the In a Meeting script. The end result looks like:

meeting-etiquette-applescripts-menu.png

Create a “In the Meeting” Script

In the AppleScript Editor application, select New and copy the following goodness into it. Save it it in ~/Library/Scripts and that will put it up in the Script pull-down (described above).

-- 1. Hide the Dock
tell application "System Events" to set the autohide of the dock preferences to true

-- 2. Disable notifications from the Mac
do shell script "defaults -currentHost write ~/Library/Preferences/ByHost/com.apple.notificationcenterui doNotDisturb -boolean true"
set theDate to quoted form of (do shell script "date -u +\"%Y-%m-%d %H:%M:%S +0000\"")
do shell script "defaults -currentHost write ~/Library/Preferences/ByHost/com.apple.notificationcenterui doNotDisturbDate -date " & theDate
do shell script "killall NotificationCenter"

-- 3. Tell Skype that I'm in a Meeting
tell application "System Events" to set SkypeIsRunning to (count of (every process whose name is "Skype")) > 0

if SkypeIsRunning then
        tell application "Skype"
                send command "SET USERSTATUS DND" script name "IMStatus"
                send command "SET PROFILE MOOD_TEXT I'm in a meeting" script name "IMStatus"
        end tell
end if

-- 4. Tell Caffeine to activate (Optional if you don't have it)
-- tell application "Caffeine" to turn on

-- 5. Tell Chrome to go full screen (Optional, but should be last step)
tell application "Google Chrome" to activate

tell application "System Events"
        keystroke "f" using {command down, shift down}
end tell

Create an “Out of Meeting” Script

Of course, you’ll want to build an opposite Out of Meeting script, like:

-- Set your Skype catch-phrase here:
set statusMsg to "Hi there."

-- 1. Show the Dock
tell application "System Events" to set the autohide of the dock preferences to false

-- 2. Enable notifications from the Mac
do shell script "defaults -currentHost write ~/Library/Preferences/ByHost/com.apple.notificationcenterui doNotDisturb -boolean false"
try
  do shell script "defaults -currentHost delete ~/Library/Preferences/ByHost/com.apple.notificationcenterui doNotDisturbDate"
end try
do shell script "killall NotificationCenter"

-- 3. Tell Skype I'm available
tell application "System Events" to set SkypeIsRunning to (count of (every process whose name is "Skype")) > 0

if SkypeIsRunning then
        tell application "Skype"
                send command "SET USERSTATUS ONLINE" script name "ComeBack"
                send command "SET PROFILE MOOD_TEXT " & statusMsg script name "ComeBack"
        end tell
end if

-- 4. Turn off Caffeine ... Optional
-- tell application "Caffeine" to turn off

Hopefully, this will help lower the distractions in your online meetings.